April 26, 2006

Coverage: references listed below

XSLT and XPath

XSLT is a language for transforming XML documents to XML and various other formats including plain text and HTML
- alter <xsl:output method="..."> tag
- means XSLT can output XHTML and VoiceXML
XSLT stylesheets are written in XML!
- we've seen this before
- means XSLT can be used to transform XSLT stylesheets themselves
XSLT can be used to query XML documents
XSLT uses XPath as an expression language to refer to parts of the XML document
XSLT C library for Gnome
- C library of functions for conducting XSL Transformations from within a C program
- comes bundled with an easy-to-use, command-line XSLT processor
  - installed as /bin/xsltproc on the Suns in the AN 131 lab
a stylesheet is a series of pattern-action rules called templates (<xsl:template match="...">)
- in this sense, XSLT is like Prolog
order of templates in stylesheet is irrelevant to output
- in this sense, XSLT is slightly different than Prolog
strategy used to search rules is built-in
- in this sense, XSLT is like Prolog
- Prolog uses DFS
- XSLT uses a conflict-resolution algorithm
  - can be altered by associating priorities to rules
    - can be viewed as a way to change the semantics of the language/interpreter
XSLT is not an imperative language
- a more declarative/logic language like Prolog
- double-edged sword: search strategy comes for free means
  - you don't have to code it yourself as you would have to when using an imperative language
  - the lexical layout of the program does not reveal much about the flow of control as it does in an imperative program
<xsl:apply-templates/> continues recursive processing
XSLT is Turing-complete

Querying Instructor-Course Data Using XSLT

converting the instructor-course data to HTML (using only one template)

toHTML.xsl:

<?xml version="1.0"?>

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

<xsl:output method="html"/>

<xsl:template match="/">
   <html>
   <head>
      <title>CPS Instructor/Course WebpageInstructors</h1>
      <ul>
      <xsl:for-each select="/*/instructor">
         <li><xsl:value-of select="name"/></li>
      </xsl:for-each>
      </ul>
      <h1>Courses</h1>
      <ul>
      <xsl:for-each select="*/course">
         <li>
            <b><xsl:value-of select="dept"/>
               <xsl:text> </xsl:text>
               <xsl:value-of select="no"/></b>
               <xsl:text>: </xsl:text>
               <xsl:value-of select="credits"/>
          </li>
      </xsl:for-each>
      </ul>
   </body>
   </html>
</xsl:template>

</xsl:stylesheet>

note difference between absolute (used for <instructor>s) and relative (used for <course>s) XPaths
can we use a <br> tag here?

converting the instructor-course data to XHTML (now using multiple templates)

toXHTML.xsl:

<?xml version="1.0"?>

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

<xsl:output method="xml"/>

<xsl:template match="instructor">
   <li><xsl:value-of select="name"/></li>
</xsl:template>

<xsl:template match="course">
   <li>
      <b><xsl:value-of select="dept"/>
         <xsl:text> </xsl:text>
         <xsl:value-of select="no"/></b>
         <xsl:text>: </xsl:text>
         <xsl:value-of select="credits"/>
   </li>
</xsl:template>

<xsl:template match="/">
   <html>
   <head>
      <title>CPS Instructor/Course Webpage</title>
   </head>
   <body>
      <h1>Instructors
      <ul>
         <xsl:apply-templates select="*/instructor"/>
      </ul>
      <h1>Courses</h1>
      <ul>
         <xsl:apply-templates select="*/course"/>
      </ul>

   </body>
   </html>
</xsl:template>

</xsl:stylesheet>

query for instructors

instructors.xsl:

<?xml version="1.0"?>

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

<xsl:output method="xml"/>

<!-- query for instructors -->
<xsl:template match="*">
   <xsl:copy>
      <xsl:apply-templates/>
   </xsl:copy>
</xsl:template>

<xsl:template match="course"/>

</xsl:stylesheet>

notice that we wrote the query to remove what we don't want rather than to return what we do want
- means that we have to prune out more as we add different elements to the input XML document
notice also that attributes are not copied over into result tree (by default)

query for instructors and their attributes

instructors-attribs.xsl:

<?xml version="1.0"?>

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

<xsl:output method="xml"/>

<!-- query for instructors and their attributes -->
<xsl:template match="*">
   <xsl:copy>
      <xsl:for-each select="@*"><xsl:copy/></xsl:for-each>
      <xsl:apply-templates/>
   </xsl:copy>
</xsl:template>

<xsl:template match="course"/>

</xsl:stylesheet>

query for instructors who teach CPS 445 or CPS 445

4445instructors.xsl:

<?xml version="1.0"?>

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

<xsl:output method="xml"/>


<!-- query for instructors who teach CPS 444 or CPS 445 -->
<xsl:template match="*">
   <xsl:copy>
      <xsl:apply-templates/>
   </xsl:copy>
</xsl:template>

<xsl:template match="instructor[contains(@teaches, '444')] |
                     instructor[contains(@teaches, '445')]">
   <xsl:copy>
      <xsl:apply-templates/>
   </xsl:copy>
</xsl:template>

<xsl:template match="instructor"/>

<xsl:template match="course"/>

</xsl:stylesheet>

notice whitespace is copied over into result tree (in prior query as well)
use <xsl:strip-space elements="*"/> after <xsl:output method="xml"/> to strip out whitespace

query for instructors and CPS 150 over a modified XML document (icd6.xml)
- now we have added different elements
- illustrates the use of a conditional

if.xsl

<?xml version="1.0"?>

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

<xsl:output method="xml"/>

<xsl:strip-space elements="*"/>

<!-- query for instructors and CPS 150 -->
<xsl:template match="*">
   <xsl:copy>
      <xsl:apply-templates/>
   </xsl:copy>
</xsl:template>

<xsl:template match="course">
   <xsl:if test="no[text()='150']">
   <xsl:copy>
      <xsl:apply-templates/>
   </xsl:copy>
   </xsl:if>
</xsl:template>

<xsl:template match="yea-last-day"/>

</xsl:stylesheet>

stylesheet to transform icd3.xml into icd2.xml

transform.xml:

<?xml version="1.0"?>

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

<xsl:output method="xml"/>

<xsl:template match="*">
   <xsl:copy>
      <xsl:apply-templates/>
   </xsl:copy>
</xsl:template>

<xsl:template match="/">
   <xsl:for-each select="*/instructor">
      <xsl:copy>

         <xsl:apply-templates/>

         <xsl:variable name="tmp" select="@teaches"/>

         <xsl:for-each select="following::course[contains($tmp, @cid)]">
            <xsl:element name="teaches">
               <xsl:copy>
                  <xsl:apply-templates/>
               </xsl:copy>
            </xsl:element>
         </xsl:for-each>

         <xsl:for-each select="preceding::course[contains($tmp, @cid)]">
            <xsl:element name="teaches">
               <xsl:copy>
                  <xsl:apply-templates/>
               </xsl:copy>
            </xsl:element>
         </xsl:for-each>

      </xsl:copy>
   </xsl:for-each>
</xsl:template>

</xsl:stylesheet>

here the fact that attributes are not copied is attractive
notice the use of axes (child is the default)
- we need both preceding and following
  - remember our schema
we used a variable here to facilitate the join of instructors and courses
- what about a nested <xsl:for-each select="...">?

Helpful Sites

Files Used In Class

icd2.xml (captures who teaches what using replication)
icd3.xml (captures who teaches what using ID's and IDREF's
icd6.xml (instructor-course data with an extra course and element)
toHTML.xsl (XSLT stylesheet to convert the instructor-course data to HTML)
icd.html (output of toHTML.xsl over icd3.xml)
toXHTML.xsl (XSLT stylesheet to convert the instructor-course data to XHTML)
instructors.xsl (query for instructors)
instructors-attribs.xsl (query for instructors and their attributes)
4445instructors.xsl (query for instructors who teach CPS 444 and CPS 445)
if.xsl (query for instructors and CPS 150)
transform.xsl (stylesheet to transform icd3.xml into icd2.xml)

References

[DMXD]	S. S. Chawathe. Describing and Manipulating XML Data. Bulletin of the IEEE Computer Society Technical Committee on Data Engineering, Vol. 22, No. 3, pp. 3-9, September 1999.
[LXML]	E. T. Ray. Learning XML. O'Reilly, Second edition, 2003.